SPARQL Endpoint

The public SPARQL endpoint of the Microsoft Academic Knowledge Graph is provided at

http://ma-graph.org/sparql

Example SPARQL queries:

  • Title and publication date of 100 papers which have been published in the context of “Night air” (as scientific concept):
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX magc: <http://ma-graph.org/class/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX prism: <http://prismstandard.org/namespaces/1.2/basic/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT distinct ?paperTitle ?paperPubDate
WHERE {
?field rdf:type magc:FieldOfStudy .
?field foaf:name "Night air"^^xsd:string .
?paper fabio:hasDiscipline ?field .
?paper dcterms:title ?paperTitle .
?paper prism:publicationDate ?paperPubDate .
}
LIMIT 100
  • Top 10 institutions in the area of machine learning, ranked by the number of citations of their papers:
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX magp: <http://ma-graph.org/property/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX org: <http://www.w3.org/ns/org#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT ?affilName ?citCountAffil
WHERE {
?field rdf:type <http://ma-graph.org/class/FieldOfStudy> .
?field foaf:name "Machine learning"^^xsd:string .
?paper fabio:hasDiscipline ?field .
?paper dcterms:creator ?author .
?author org:memberOf ?affiliation .
?affiliation foaf:name ?affilName .
?affiliation magp:citationCount ?citCountAffil .
}
GROUP BY ?affilName ?citCountAffil
ORDER BY DESC(?citCountAffil)
LIMIT 100
  • Top 100 researchers which have been most frequently to conferences in Honolulu, Hawaii:
PREFIX magp: <http://ma-graph.org/property/>
PREFIX dcterms: <http://purl.org/dc/terms/> 
PREFIX foaf: <http://xmlns.com/foaf/0.1/> 
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX dbr: <http://dbpedia.org/resource/>

SELECT ?authorName (COUNT(?confInstance) AS ?freq) 
WHERE {
 ?paper dcterms:creator ?author .
 ?author foaf:name ?authorName .
 ?paper magp:appearsInConferenceInstance ?confInstance .
 ?confInstance dbo:location dbr:Honolulu . }
GROUP BY ?authorName 
ORDER BY DESC(?freq)
LIMIT 100